pcu: Introduce test TC_cs_max_dl and TC_dl_cs1_to_cs4
Change-Id: If847d091f3f4e6a7c77fbadc7280423637c50b35
diff --git a/pcu/PCU_Tests.ttcn b/pcu/PCU_Tests.ttcn
index aa4d28d..4df040e 100644
--- a/pcu/PCU_Tests.ttcn
+++ b/pcu/PCU_Tests.ttcn
@@ -867,6 +867,101 @@
f_shutdown(__BFILE__, __LINE__, final := true);
}
+/* Verify scheduling of multiple Downlink data blocks, enough to reach CS4 */
+function f_dl_data_exp_cs(template CodingScheme exp_cs := ?) runs on RAW_PCU_Test_CT {
+ var octetstring data := f_rnd_octstring(1000);
+ var RlcmacDlBlock prev_dl_block, dl_block;
+ var uint32_t ack_fn;
+ var uint32_t fn;
+ var GprsMS ms;
+ var integer tx_data_remain := 5;
+ var integer bsn := 0;
+
+ /* Establish BSSGP connection to the PCU */
+ f_bssgp_establish();
+
+ ms := g_ms[0]; /* We only use first MS in this test */
+ f_bssgp_client_llgmm_assign(TLLI_UNUSED, ms.tlli);
+
+ /* SGSN sends some DL data, PCU will page on CCCH (PCH) */
+ BSSGP[0].send(ts_BSSGP_DL_UD(ms.tlli, data));
+ f_ms_exp_dl_tbf_ass_ccch(ms, PCU_IF_SAPI_PCH);
+
+ /* Wait timer X2002 and DL block is available after CCCH IMM ASS */
+ f_sleep(X2002);
+
+ for (var integer i := 0; i < 250; i := i + 1) {
+ bsn := i mod 128;
+ f_rx_rlcmac_dl_block(dl_block, fn);
+
+ if (match(dl_block, tr_RLCMAC_DUMMY_CTRL)) {
+ /* No more data to receive, done */
+ break;
+ }
+
+ f_rlcmac_dl_block_exp_data(dl_block, ?, bsn, cs_gprs_any);
+
+ /* Keep Ack/Nack description updated */
+ f_acknackdesc_ack_block(ms.dl_tbf.acknack_desc, dl_block);
+
+ /* TDMA frame number on which we are supposed to send the ACK */
+ if (dl_block.data.mac_hdr.mac_hdr.rrbp_valid) {
+ ack_fn := f_dl_block_ack_fn(dl_block, fn);
+ f_ms_tx_ul_block(ms, ts_RLCMAC_DL_ACK_NACK(ms.dl_tbf.tfi, ms.dl_tbf.acknack_desc), ack_fn);
+ if (tx_data_remain != 0) {
+ /* Submit more data from time to time to keep the TBF ongoing */
+ BSSGP[0].send(ts_BSSGP_DL_UD(ms.tlli, data));
+ tx_data_remain := tx_data_remain - 1;
+ }
+ }
+ prev_dl_block := dl_block;
+ }
+
+ bsn := (bsn + 127) mod 128; /* previous bsn: bsn -1 */
+ f_rlcmac_dl_block_exp_data(prev_dl_block, ?, bsn, exp_cs);
+
+
+ f_shutdown(__BFILE__, __LINE__, final := true);
+}
+
+/* Verify DL CS above "cs max" set by VTY is never used */
+testcase TC_cs_max_dl() runs on RAW_PCU_Test_CT {
+ /* Initialize NS/BSSGP side */
+ f_init_bssgp();
+ /* Initialize GPRS MS side */
+ f_init_gprs_ms();
+
+ /* Initialize the PCU interface abstraction */
+ f_init_raw(testcasename(), ts_PCUIF_INFO_default(c_PCUIF_Flags_noMCS));
+
+ /* Set maximum allowed DL CS to 3 */
+ g_cs_initial_dl := 1;
+ g_cs_max_dl := 3;
+ f_pcuvty_set_allowed_cs_mcs();
+ f_pcuvty_set_link_quality_ranges();
+
+ f_dl_data_exp_cs(f_rlcmac_block_int2cs_mcs(g_cs_max_dl, false));
+}
+
+/* Check DL CS4 is used in good link conditions if allowed by config */
+testcase TC_dl_cs1_to_cs4() runs on RAW_PCU_Test_CT {
+ /* Initialize NS/BSSGP side */
+ f_init_bssgp();
+ /* Initialize GPRS MS side */
+ f_init_gprs_ms();
+
+ /* Initialize the PCU interface abstraction */
+ f_init_raw(testcasename(), ts_PCUIF_INFO_default(c_PCUIF_Flags_noMCS));
+
+ /* Set initial DL CS to 1 & maximum allowed DL CS to 4 */
+ g_cs_initial_dl := 1;
+ g_cs_max_dl := 4;
+ f_pcuvty_set_allowed_cs_mcs();
+ f_pcuvty_set_link_quality_ranges();
+
+ f_dl_data_exp_cs(f_rlcmac_block_int2cs_mcs(g_cs_max_dl, false));
+}
+
/* Verify PCU drops TBF after some time of inactivity. */
testcase TC_t3169() runs on RAW_PCU_Test_CT {
var PCUIF_info_ind info_ind;
@@ -2915,6 +3010,8 @@
execute( TC_cs_initial_ul() );
execute( TC_cs_max_ul() );
execute( TC_cs_initial_dl() );
+ execute( TC_cs_max_dl() );
+ execute( TC_dl_cs1_to_cs4() );
execute( TC_t3169() );
execute( TC_t3193() );
execute( TC_countdown_procedure() );